solved day 5 !

src/day5.ml

@@ -0,0 +1,83 @@
+open Containers
+
+let crane_drop stacks index box =
+  let stack = Array.get stacks index in
+  Array.set stacks index (box @ stack)
+;;
+
+let crane_lift stacks index count =
+  let stack = Array.get stacks index in
+  let boxes, rest = List.take_drop count stack in
+  Array.set stacks index rest;
+  boxes
+;;
+
+let crane_move1 stacks (count, lift, drop) =
+  List.iter
+    (fun _ ->
+      let box = crane_lift stacks lift 1 in
+      crane_drop stacks drop box)
+    List.Infix.(0 --^ count)
+;;
+
+let crane_move stacks (count, lift, drop) =
+  let boxes = crane_lift stacks lift count in
+  crane_drop stacks drop boxes
+;;
+
+let init_stacks lines =
+  let stacks = Array.init 10 (fun _ -> []) in
+  let rec parse_line index line =
+    let chunk, rest = String.take_drop 4 line in
+    match%pcre chunk with
+    | {|(?<letter>\w)|} ->
+      crane_drop stacks index [ letter ];
+      parse_line (index + 1) rest
+    | {| |} -> parse_line (index + 1) rest
+    | _ -> ()
+  in
+  List.iter (parse_line 1) (List.rev lines);
+  stacks
+;;
+
+let move_stacks stacks lines crane_move =
+  let parse_line =
+    function%pcre
+    | {|move (?<count>\d+) from (?<lift>\d+) to (?<drop>\d+)|} ->
+      int_of_string count, int_of_string lift, int_of_string drop
+    | line -> failwith @@ Printf.sprintf "could not parse line '%s'" line
+  in
+  List.iter
+    (fun line ->
+      let instructions = parse_line line in
+      crane_move stacks instructions)
+    lines
+;;
+
+let parse_input lines =
+  let init_lines, lines = List.take_drop_while (String.starts_with ~prefix:"[") lines in
+  let move_lines = List.drop_while Fun.(not % String.starts_with ~prefix:"move") lines in
+  init_lines, move_lines
+;;
+
+let solve crane_move =
+  let init_lines, move_lines = parse_input @@ Utils.lines_of_input 5 in
+  let stacks = init_stacks init_lines in
+  let () = move_stacks stacks move_lines crane_move in
+  Array.fold_left
+    (fun acc stack ->
+      match stack with
+      | top :: _ -> acc ^ top
+      | [] -> acc)
+    ""
+    stacks
+;;
+
+let part1 () = solve crane_move1
+let part2 () = solve crane_move
+
+let print () =
+  Printf.(
+    printf "Day 5.1: %s\n" @@ part1 ();
+    printf "Day 5.2: %s\n" @@ part2 ())
+;;